primitive types

The primitive, or intrinsic types are those which are simple datatypes (they have no additional data attributes). Objects are not primitive types. Primitive types are passed by value. Primitive types cannot be extended. The primitive types in ChucK are:

• int : integer (signed)
• float : floating point number (in ChucK, a float is by default double-precision)
• time : ChucKian time
• dur : ChucKian duration
• void : (no type)
• vec3 : 3D vector (x, y, z) of floats (see vec3.ck example); can also be used as a slew interpolator (see interpolate.ck)
• vec4 : 4D vector (x, y, z, w) of floats (see vec4.ck example)
• complex : complex number in rectangular form a + bi (see below)
• polar : complex number in polar form (see below)
  

For a summary of operations on these types, go to operations and operators.

All other types are derived from 'object', either as part of the ChucK standard library, or as a new class that you create. For specification, go to classes and objects.

values (literals)

Literal values are specified explicitly in code and are assigned a type by the compiler. The following are some examples of literal values:

int:

42

int (hexidecimal):

0xaf30

float:

1.323

dur:

5.5::second

In the above code, second is an existing duration variable. For more on durations, see the manipulating time section.

variables

Variables are locations in memory that hold data. Variables have to be declared in ChucK before they are used. For example, to declare a variable of type int called foo:

 // declare an 'int' called 'foo'
 int foo;

We can assign a value to an existing variable by using the ChucK operator (=>). This is one of the most commonly used operators in ChucK, it's the way to do work and take action! We will discuss this family of operators in operators and operations.

 // assign value of 2 to 'foo'
 2 => foo;

It is possible to combine the two statements into one:

 // assign 2 to a new variable 'foo' of type 'int'
 2 => int foo;

To use a variable, just refer to it by name:

 // debug-print the value of foo
 <<< foo >>>;

To update the value of foo, for example:

 // multiply 'foo' by 10, assign back to 'foo'
 foo * 10 => foo;

You can also do the above using a *=>(mult-chuck):

 // multiply 'foo' by 10, and then assign to 'foo'
 10 *=> foo;

Here is an example of a duration:

 // assign value of '5 seconds' to new variable bar
 5::second => dur bar;

Once you have bar, you can inductively use it to construct new durations:

 // 4 bar, a measure?
 4::bar => dur measure;

Since time is central to programming ChucK, it is important to understand time, dur, the relationship and operations between them. There is more information in the manipulating time section.

reference types

Reference types are types which inherit from the object class. Some default reference types include:

• Object : base type that all classes inherit from (directly or indirectly)
• array : N-dimensional ordered set of data (of the same type)
• Event : fundamental, extendable, synchronization mechanism
• UGen : extendable unit generator base class
• string : string (of characters)

New classes can be created. All classes are reference types. We will leave the full discussion to the objects and classes section.

complex types

Two special primitive types are available to to represent complex data, such as the output of an FFT: complex and polar. A complex number of the form a + bi can be declared as

 #(2,3) => complex cmp; //cmp is now 2 + 3i 

where the #(...) syntax explicitly denotes a complex number in rectangular form. Similarly, explicit complex numbers can be manipulated directly:

 #(5, -1.5) => complex cmp; // cmp is 5 - 1.5i
 #(2,3) + #(5,6) + cmp => complex sum; // sum is now 12 + 7.5i

The (floating point) real and imaginary parts of a complex number can be accessed with the .re and .im components of a complex number:

 #(2.0,3.5) => complex cmp;
 cmp.re => float x; // x is 2.0
 cmp.im => float y; //y is 3.5

The polar type offers an equivalent, alternative representation of complex numbers in terms of a magnitude and phase value. A polar representation of a complex number can be declared as

 %(2, .5*pi) => polar pol; // pol is 2∠.5π

The magnitude and phase values can be accessed via .mag and .phase:

 %(2, .5*pi) => polar pol;
 pol.mag => float m; // m is 2
 pol.phase => float p; //p is .5π

polar and complex representations can be cast to each other and multiplied/added/assigned/etc.:

 %(2, .5*pi) => polar pol;
 #(3, 4) => complex cmp;
 pol $ complex + #(10, 3) + cmp => complex cmp2;
 cmp $ polar + %(10, .25*pi) - pol => polar pol2;